Отсутствие проверки на NULL для полей из присоединяемых таблиц (FieldsFromJoinsWithoutIsNull)

Тип	Поддерживаются языки	Важность	Включена по умолчанию	Время на исправление (мин)	Теги
Ошибка	BSL OS	Критичный	Нет	2	sql suspicious unpredictable

Описание диагностики

Диагностика проверяет поля из левых, правых, полных соединений, для которых не выполняется проверка с помощью ЕСТЬNULL() или НЕ ЕСТЬ NULL или или ЕСТЬ НЕ NULL.

В запросах нельзя использовать реквизиты из присоединяемых слева или справа таблиц без проверки значений на NULL. Указанное обращение может приводить к ошибкам, если условие соединения не выполнено и нет подходящих записей в левой или правой таблице. В итоге в результате запроса можно получить неожиданные данные и система может повести себя неверным образом.

Важно помнить, что любое сравнение значения NULL с любым другими выражением всегда ложно, даже сравнение NULL и NULL всегда ложно. Смотрите ниже пример подобных неверных сравнений. Поэтому нужно правильно выполнять сравнение с NULL - или через оператор ЕСТЬ NULL или через функцию ЕСТЬNULL().

Также достаточно часто используются левые\правые соединения, хотя данные позволяют использовать внутреннее соединение, в этом случае не нужны проверки на NULL.

Или дополнительные проверки реквизитов выполняются в коде 1С, а не в тексте запроса. Подобные обращения затрудняют чтение кода и рефакторинг кода, т.к. контекст обращения к реквизиту приходится учитывать в нескольких местах. В дополнение нужно учитывать, что простые проверки в запросе выполняются чуть быстрее и проще, чем в интерпретируемом коде 1С.

Указанные проблемы являются одними из самых частых ошибок разработчиков 1С самого разного уровня компетенций.

Примеры

Пример, показывающий проблемы сравнения с NULL - в примере 2 таблицы соединяются заведомо неверно и приведены разные способы сравнения

ВЫБРАТЬ
  ВЫБОР
    КОГДА Левая.Поле2 = 0 ТОГДА "Равно 0 - не работает"
    КОГДА Левая.Поле2 <> 0 ТОГДА "НЕ Равно 0 - не работает"
    КОГДА Левая.Поле2 = NULL ТОГДА "Равно NULL - не работает"
    КОГДА Левая.Поле2 ЕСТЬ NULL ТОГДА "ЕСТЬ NULL - этот вариант работает"
    КОГДА ЕСТЬNULL(Левая.Поле2, 0) = 0  ТОГДА "ЕСТЬNULL() - этот вариант также работает"
    ИНАЧЕ "Иначе"
  КОНЕЦ
ИЗ
  Первая КАК Первая
  ЛЕВОЕ СОЕДИНЕНИЕ Левая КАК Левая
  ПО Ложь // чтобы не было соединения

Подозрительный код обращения к реквизиту присоединенной таблицы

ВЫБРАТЬ 
  ДокументыПродажи.Ссылка КАК ДокПродажи,
  РегистрПродажи.Сумма КАК Сумма // здесь ошибка
ИЗ Документ.РеализацияТоваровУслуг КАК ДокументыПродажи
ЛЕВОЕ СОЕДИНЕНИЕ  РегистрНакопления.Продажи КАК РегистрПродажи
ПО ДокументыПродажи.Ссылка = РегистрПродажи.Документ

Правильно

ВЫБРАТЬ 
  ДокументыПродажи.Ссылка КАК ДокПродажи,
  ЕстьNULL(РегистрПродажи.Сумма, 0) КАК Сумма
ИЗ Документ.РеализацияТоваровУслуг КАК ДокументыПродажи
ЛЕВОЕ СОЕДИНЕНИЕ  РегистрНакопления.Продажи КАК РегистрПродажи
ПО ДокументыПродажи.Ссылка = РегистрПродажи.Документ

Также правильно

ВЫБРАТЬ 
  ДокументыПродажи.Ссылка КАК ДокПродажи,
  ВЫБОР КОГДА РегистрПродажи.Сумма Есть NULL ТОГДА 0
  ИНАЧЕ  РегистрПродажи.Сумма 
  КОНЕЦ КАК Сумма
ИЗ Документ.РеализацияТоваровУслуг КАК ДокументыПродажи
ЛЕВОЕ СОЕДИНЕНИЕ  РегистрНакопления.Продажи КАК РегистрПродажи
ПО ДокументыПродажи.Ссылка = РегистрПродажи.Документ

И еще возможный вариант

ВЫБРАТЬ 
  ДокументыПродажи.Ссылка КАК ДокПродажи,
  РегистрПродажи.Сумма КАК Сумма
ИЗ Документ.РеализацияТоваровУслуг КАК ДокументыПродажи
ЛЕВОЕ СОЕДИНЕНИЕ  РегистрНакопления.Продажи КАК РегистрПродажи
ПО ДокументыПродажи.Ссылка = РегистрПродажи.Документ
ГДЕ
    РегистрПродажи.Документ ЕСТЬ НЕ NULL
    //или НЕ РегистрПродажи.Документ ЕСТЬ NULL

Последний вариант - не самый лучший, т.к. в нем фактически эмулируется внутреннее соединение. И проще явно указать ВНУТРЕННЕЕ СОЕДИНЕНИЕ вместо использования левого соединения с проверкой ЕСТЬ НЕ NULL или НЕ ЕСТЬ NULL

Источники

• Использование функции ЕСТЬNULL() - Стандарт
• Понятие "пустых" значений - Методические рекомендации 1С
  • Чем отличается значение типа Неопределено и значение типа Null? - Методические рекомендации 1С
• Особенности связи с виртуальной таблицей остатков - Методические рекомендации 1С
• Сортировка по полю запроса, которое может потенциально содержать NULL - статья "Упорядочивание результатов запроса" - Стандарт
• Поля иерархического справочника могут содержать NULL - Методические рекомендации 1С
  • Как получить записи иерархической таблицы и расположить их в порядке иерархии - Методические рекомендации 1С
• Как получить данные из разных таблиц для одного и того же поля - онлайн-книга "Язык запросов 1С:Предприятия"

Сниппеты

Экранирование кода

// BSLLS:FieldsFromJoinsWithoutIsNull-off
// BSLLS:FieldsFromJoinsWithoutIsNull-on

Параметр конфигурационного файла

"FieldsFromJoinsWithoutIsNull": false